Купить Matlab  |  Mathematica  |  Mathcad  |  Maple  |  Statistica  |  Другие пакеты Поиск по сайту
Internet-класс  |  Примеры  |  Методики  |  Форум  |  Download
https://hub.exponenta.ru/


Maple Essentials On-line Tour.
© 2000 Seattle Central Community College.
Перевод В.А.Цыбулько
 
Раздел 05. Функции: Определение, Вычисление, Графики (Functions: Defining, Evaluating and Graphing)
 

© 2000 Seattle Central Community College
публикуется с разрешения

[Maple OLE 2.0 Object] [Maple OLE 2.0 Object]

ZIP-архив (38 Кб, Maple)

К предыдущему разделуК следующему разделу

В этом разделе Вы научитесь определять функции в Maple, находить их значения. Кроме того, Вы сможете развить навыки решения уравнений и построения графиков.

05. 01  Определение и удаление функций в Maple

Упражнение 5.1

05. 02  Вычисление значений функции

Упражнение 5.2

05. 03  Решение функциональных уравнений

05. 04  Построение графиков функций

Упражнение 5.3

Упражнение 5.4

Упражнение 5.5

 

05. 01  Определение и удаление функций в Maple 

* Defining and Clearing a Function in Maple *

В Maple для определения функции и её выделения на фоне обычных выражений используется специальная форма записи.

Например, функция f(x) = cos(Pi*x)+3 определяется так:

> f:=x->cos(Pi*x)+3;

f := proc (x) options operator, arrow; cos(Pi*x)+3 ...

"Прочитаем": величина х "переводится" в выражение cos(Pi*x)+3 , которому присваивается имя f ( это соответствует духу определения функции f(x) ). Кроме известного Вам оператора присваивания := , в этой конструкции используются символы " минус " и " больше ", образующие " стрелку " -> .

Традиционная форма записи такой функции: f(x) = cos(Pi*x)+3 .

Сравним формы, которые используются в Maple для определения функции и аналогичного выражения :

> y:=(x + 2)/(x^3 + 5*x + 2);

y := (x+2)/(x^3+5*x+2)

> f:=x->(x + 2)/(x^3 + 5*x + 2);

f := proc (x) options operator, arrow; (x+2)/(x^3+5...

Конечно, и формы вывода на дисплей также разнятся. Наличие стрелки - важнейший отличительный знак функции в Maple .

Упражнение 5.1

Определите функцию h(x) = x^3*sin(2*x+1) .

Учебная площадка 5.1

>

>

>

Ответ 5.1

> h:= x-> x^3*sin(2*x+1);

h := proc (x) options operator, arrow; x^3*sin(2*x+...

Если Вы единожды определили функцию, то Maple это запомнит до окончания рабочей сессии. Если Вы вдруг захотите переопределить функцию f(x), например, на ln(cos 5x) , то просто напечатайте:

> f:=x->ln(cos(5*x));

f := proc (x) options operator, arrow; ln(cos(5*x))...

Можно вывести текущий вид функции f(x):

> f(x);

ln(cos(5*x))

Можно избавить переменную f от её функциональных обязанностей командой:

> f:='f';

f := 'f'

> f(x);

f(x)

Напомним, что Maple обладает прекрасной способностью очищать свою память по команде restart . При этом все введенные Вами функции будут стерты.

05. 02  Вычисление значений функции

* Evaluating a Function *

Если Вы уже определили функцию, то можете в любой момент и в любом месте Maple-документа находить как численные, так и символьные её значения. Во избежание недоразумений, перед вводом новой функции, избавьте от возможного прошлого её имя:

> f:='f';

f := 'f'

> f:=x->3*x+x^2;

f := proc (x) options operator, arrow; 3*x+x^2 end ...

> f(-1);

-2

> f(2+sqrt(5));

6+3*sqrt(5)+(2+sqrt(5))^2

> evalf(f(2+sqrt(5)));

30.65247584

> f(x+4);

3*x+12+(x+4)^2

> simplify(%);

11*x+28+x^2

> (f(x+h)-f(x))/h;

(3*h+(x+h)^2-x^2)/h

> simplify(%);

3+2*x+h

Если определено несколько функций, то легко из них создать композицию ( сложную функцию ):

> g:=x->cos(x)+1;

g := proc (x) options operator, arrow; cos(x)+1 end...

> f(g(Pi/3));

27/4

> j:=x->g(f(x));

j := proc (x) options operator, arrow; g(f(x)) end ...

> j(x);

cos(3*x+x^2)+1

Упражнение 5.2

Определить функцию s(t) = (3+t^2)/sqrt(3*t+1) , а затем найдите s(2), s(t-3) и s(t) - s(3) и результаты упростите. Не забудьте о стрелках!

Учебная площадка 5.2

>

>

>

>

>

>

>

>

>

>

Ответ 5.2

> s:= t-> (3 + t^2)/(sqrt(3*t+1));

s := proc (t) options operator, arrow; (3+t^2)/sqrt...

> s(2);

sqrt(7)

> s(t - 3);

(3+(t-3)^2)/(sqrt(3*t-8))

> simplify (%);

(12+t^2-6*t)/(sqrt(3*t-8))

> s(t) - s(3);

(3+t^2)/(sqrt(3*t+1))-6/5*sqrt(10)

> simplify(%);

1/5*(15+5*t^2-6*sqrt(10)*sqrt(3*t+1))/(sqrt(3*t+1))...

Заметьте, что если Вы определили указанным образом функцию, уже нет необходимости использовать команду subs для нахождения значений функции, как в случае выражений.

05. 03  Решение функциональных уравнений

* Solving Equations involving Functions *

Заранее определив функцию, Вы можете составить и решить ( точно или приближенно ) содержащее её уравнение.

> g:='g';

g := 'g'

> g:=t->t^3-6*t^2+6*t+8;

g := proc (t) options operator, arrow; t^3-6*t^2+6*...

> solve(g(t)=0,t);

4, 1+sqrt(3), 1-sqrt(3)

> fsolve(g(t)=0,t);

-.7320508076, 2.732050808, 4.

05. 04  Построение графиков функций

* Graphing a Function *

Для построения графиков функций используется всё та же команда plot .

> h:='h'; y:='y'; x:='x';

h := 'h'

y := 'y'

x := 'x'

> h:=x->x*exp(-x);

h := proc (x) options operator, arrow; x*exp(-x) en...

> plot(h(x),x=-1..4,y=-2..1);

[Maple Plot]

Как и в случае выражений, в одной системе координат можно построить графики сразу нескольких функций.

Определим функцию f(x) = 4/(x^2+1) и построим одновременно графики функций f(x) , f(x+1) , f(x-3) и f(x-6) . Кривые получаются друг из друга параллельным переносом. Попробуйте установить соответствие между функциями и их графиками.

> f:=x->2/(x^2+1);

f := proc (x) options operator, arrow; 2*1/(x^2+1) ...

> plot([f(x),f(x+1),f(x-3),f(x-6)],x=-5..10,y=-1..3);

[Maple Plot]

Упражнение 5.3

Определите функцию f(x) = 2*x-abs(x^2-5) , а затем:

a) Найдите значение f(6.5).

b) Найдите и упростите значение f(z-4), где z - переменная.

c) Постройте график f(x)

d) Найдите все значения x, для которых f(x)=0.

Учебная площадка 5.3

>

>

>

>

>

>

>

>

>

>

Ответ 5.3

> f:=x->2*x-abs(x^2-5);

f := proc (x) options operator, arrow; 2*x-abs(x^2-...

> f(6.5);

-24.25

> simplify(f(z-4));

2*z-8-abs(z^2-8*z+11)

> plot(f(x),x);

[Maple Plot]

> fsolve(f(x)=0,x=0..2);

1.449489743

> fsolve(f(x)=0,x=3..4);

3.449489743

Упражнение 5.4

Определите функции g(x) = 5*exp(-.5*x) и h(x) = x+1 , а затем:

a) В одной системе координат постройте графики функций g(x) и h(x) . Поэкспериментируйте с разными областями определения и множествами значений функций.

b) Найдите координаты точки пересечения графиков этих функций при помощи левой кнопки мыши.

c) Воспользуйтесь fsolve для решения уравнения g(x) = h(x) . Согласуется ли результат с ответом на вопрос b) ?

Учебная площадка 5.4

>

>

>

>

>

>

>

>

>

>

>

>

Ответ 5.4

> g:=x->5*exp(-0.5*x);

g := proc (x) options operator, arrow; 5*exp(-.5*x)...

> h:=x->x+1;

h := proc (x) options operator, arrow; x+1 end proc...

> plot([g(x),h(x)],x=-5..5,y=-20..20);

[Maple Plot]

> plot([g(x),h(x)],x=1..2,y=1..4);

[Maple Plot]

> xval:=fsolve(g(x)=h(x),x);

xval := 1.437186898

Корень уравнения g(x)=h(x) - абсцисса точки пересечения графиков функций g(x) и h(x). Чтобы найти соответствующую ординату, вычислите значение функции g(x) или h(x) в этой точке.

> g(xval);

2.437186898

> h(xval);

2.437186898

Упражнение 5.5

Определите функцию k(x) = x+3*sin(2*x) , а затем :

a) Постройте её график на области определения [-1,8] .

b) В этот график вставьте прямую y = 4. Используя рисунок, определите число корней и их приближенное значение уравнения k(x)=4 .

c) Графиком какой одной функции можно было бы обойтись для отыскания указанных в b) корней?

d) Воспользуйтесь Maple-команду fsolve для нахождения приближенного решения уравнения k(x)=4.

Учебная площадка 5.5

>

>

>

>

>

>

>

>

Ответ 5.5

а)

> k:=x->x+3*sin(2*x);

k := proc (x) options operator, arrow; x+3*sin(2*x)...

> plot(k(x),x=-1..8);

[Maple Plot]

b)

> plot([k(x),4],x=-1..8);

[Maple Plot]

с) Мы должны построить график функции k(x) - 4 и определить абсциссы его точек пересечения с осью Ох. Они соответствуют значениям х , найденным в b).

> plot(k(x)-4,x=-1..8);

[Maple Plot]

Теперь найдём решение с помощью команды fsolve :

> fsolve(k(x)=4,x=2 .. 3.5);

3.265300793

> fsolve(k(x)=4,x=3.5 .. 5);

4.857290511

> fsolve(k(x)=4,x=5 .. 7);

5.933090071

В начало страницы К предыдущему разделуК следующему разделу

| На первую страницу | Поиск | Купить Matlab

Исправляем ошибки: Нашли опечатку? Выделите ее мышкой и нажмите Ctrl+Enter


Copyright © 1993-2022. Компания Softline. Все права защищены.

Дата последнего обновления информации на сайте: 04.03.17
Сайт начал работу 01.09.00