Предметный указатель

Команда diff(параметр1, параметр2) обеспечивает дифференцирование выражения (первый параметр) по переменной (второй параметр). Аргумент команды должен содержать по крайней мере одну переменную дифференцирования, последующие параметры интерпретируются как переменные для дифференцирования более высокого порядка. Приведем пример

> restart;diff ( x^3 * y^2, x, y);

Для выполнения многократного дифференцирования по одной переменной для сокращения записи можно использовать в команде diff оператор $.

> diff ( x^6/6!, x$6 );

> diff ((s^3+2*s-5)/(t^2-3*t), s$2, t);

Для выполнения дифференцирования применяется также дифференциальный оператор D[i](f), где f - выражение, задающее функцию, i - натуральное число. Если f функция от одного аргумента, то D(f) вычисляет производную от f, например

> D(sin);

Производная также функция одного аргумента D(f)(x) = diff(f(x), x). Таким образом D(f) эквивалентно unapply(diff(f(x), x), x).

> D(sin)(x);

> D(sin)(Pi);

Если f - функция n аргументоа, то D[i](f) вычисляет частную производную по отношению к i - тому аргументу. В общем случае D[i,j](f) эквивалентно D[i](D[j](f)), и D[](f) = f.

Приведем примеры.

> D(exp+cos^2+Pi+tan);

> D(ln);

> D(D(f));

Для многократного дифференцирования функции от одной переменной применяется оператор D@@n, где n - кратность дифференцирования.

> (D@@2)(f);

> (D@@n)(f);

Производная от композиции двух функций (сложной функции):

> D(f@g);

> D(sin@y);

Для выполнения многократного дифференцирования по заданной переменной функции от нескольких переменных применяется оператор D[i$n](f), где i - номер переменной, n - кратность дифференцирования.

> D[i$n](f);

> D[i,j](f);

> D[i,j](f)-D[j,i](f);

> D[i](D[j,i](f));

Оператор дифференцирования применяется также к функциям, заданным оператором стрелки.

> f := x -> x^2;

> D(f);

> f := (x,y) -> exp(x*y);

> D[](f);

> D[1](f);

> D[2](f);

а также в виде процедуры. Пусть

> f := proc(x) local t1,t2;
t1 := x^2;
t2 := sin(x);
3*t1*t2+2*x*t1-x*t2
end:

Вычислим производную от f по аргументу x.

> D(f);

Проверим правильность вычисления производной.

> D(f)(x) - diff(f(x),x);

Предметный указатель