Замена переменных в кратных интегралах

Вычисление якобиана для цилиндрических и сферических координат. Вычислим объем тела, ограниченного поверхностями x^2+y^2 = 4*y , z = -x^2+6 , z = 0 . То же для тела, ограниченного поверхностями x^2+y^2+z^2 = 9 , x^2+y^2+z^2 = 81 , z = 1/12*(6*x^2+6*y^2)^(1/2) , y = 0 , y = 1/3*x*3^(1/2) .

>    restart;

Цилиндрические координаты.

>    x:=r*cos(t);y:=r*sin(t);z:=z;

x := r*cos(t)

y := r*sin(t)

z := 'z'

Вычислим якобиан.

>    with(LinearAlgebra):

>    M:=Matrix([[diff(x,r),diff(x,t),diff(x,z)],[diff(y,r),diff(y,t),diff(y,z)],[diff(z,r),diff(z,t),diff(z,z)]]);

M := Matrix(%id = 3142580)

>    J:=Determinant(M);

J := cos(t)^2*r+sin(t)^2*r

>    simplify(J,trig);

r

Сферические координаты.

>    x:=r*sin(t)*cos(phi);y:=r*sin(t)*sin(phi);z:=r*cos(t);

x := r*sin(t)*cos(phi)

y := r*sin(t)*sin(phi)

z := r*cos(t)

Вычислим якобиан.

>    M:=Matrix([[diff(x,r),diff(x,t),diff(x,phi)],[diff(y,r),diff(y,t),diff(y,phi)],[diff(z,r),diff(z,t),diff(z,phi)]]);

M := Matrix(%id = 14477132)

>    J:=Determinant(M);

J := sin(t)^3*cos(phi)^2*r^2+sin(t)^3*sin(phi)^2*r^2+r^2*cos(t)^2*cos(phi)^2*sin(t)+r^2*cos(t)^2*sin(phi)^2*sin(t)

>    simplify(J,trig);

sin(t)*r^2

Для вычисления якобианов можно использовать функцию Jacobian пакета VectorCalculus.

>    restart;

>    with(VectorCalculus): 

Warning, the assigned names <,> and <|> now have a global binding




Warning, these protected names have been redefined and unprotected: *, +, ., Vector, diff, int, limit, series

Цилиндрические координаты.

>    (M,d):=Jacobian( [r*cos(t),r*sin(t),z], [r,t,z], 'determinant' );

M, d := Matrix(%id = 15054708), cos(t)^2*r+sin(t)^2*r

>    simplify(d,trig);

r

Сферические координаты.

>    (M,d):=Jacobian( [r*sin(t)*cos(phi),r*sin(t)*sin(phi),r*cos(t)], [r,t,phi], 'determinant' );

M, d := Matrix(%id = 15526696), sin(t)^3*cos(phi)^2*r^2+sin(t)^3*sin(phi)^2*r^2+r^2*cos(t)^2*cos(phi)^2*sin(t)+r^2*cos(t)^2*sin(phi)^2*sin(t)
M, d := Matrix(%id = 15526696), sin(t)^3*cos(phi)^2*r^2+sin(t)^3*sin(phi)^2*r^2+r^2*cos(t)^2*cos(phi)^2*sin(t)+r^2*cos(t)^2*sin(phi)^2*sin(t)

>    simplify(d,trig);

sin(t)*r^2

Вычислим объем первого тела.

>    restart;

>    with(plots): 

Warning, the name changecoords has been redefined

>    S:={x^2+y^2-4*y=0, z-6+x^2=0, z=0};

S := {x^2+y^2-4*y = 0, z-6+x^2 = 0, z = 0}

Нарисуем заданные поверхности.

>    implicitplot3d(S,x=-2..2,y=-1..5,z=0..6);

[Maple Plot]

Произведем сдвиг системы координат по оси y .

>    y:=v+2;

y := v+2

В новой системе координат уравнения, задающие тело, имеют более простой вид.

>    simplify(S);

{z-6+x^2 = 0, z = 0, x^2+v^2-4 = 0}

Объем тела можно посчитать по формуле Int(Int(6-x^2,x = G .. ``),y = `` .. ``) , где G - круг x^2+v^2-4 = 0 .

Перейдем к полярным координатам. Тогда интеграл можно переписать в виде повторного.

>    V:=Int(Int((6-r^2*(cos(t))^2)*abs(r),r=0..2),t=0..2*Pi);

V := Int(Int((6-r^2*cos(t)^2)*abs(r),r = 0 .. 2),t = 0 .. 2*Pi)

>    V:=value(%);

V := 20*Pi

Вычислим объем второго тела.

>    restart;

>    with(plots): 

Warning, the name changecoords has been redefined

>    S:={x^2+y^2+z^2-9=0,x^2+y^2+z^2-81=0,z=0,z-sqrt((x^2+y^2)/24)=0,y=0,y-x/sqrt(3)=0};

S := {z-1/12*(6*x^2+6*y^2)^(1/2) = 0, y-1/3*x*3^(1/2) = 0, x^2+y^2+z^2-9 = 0, x^2+y^2+z^2-81 = 0, z = 0, y = 0}

Нарисуем заданные поверхности.

>    implicitplot3d(S,x=-10..10,y=0..10,z=0..6);

[Maple Plot]

Перейдем к сферическим координатам.

>    x:=r*sin(t)*cos(phi);y:=r*sin(t)*sin(phi);z:=r*cos(t);

x := r*sin(t)*cos(phi)

y := r*sin(t)*sin(phi)

z := r*cos(t)

>    simplify(S,symbolic);

{r*cos(t) = 0, r*sin(t)*sin(phi) = 0, 1/12*r*(12*cos(t)-(6-6*cos(t)^2)^(1/2)) = 0, -1/3*r*sin(t)*(-3*sin(phi)+cos(phi)*3^(1/2)) = 0, r^2-9 = 0, r^2-81 = 0}

Интеграл сводится к виду:

>    V:=Int(Int(Int(r^2*sin(t),r=3..9),t=arccot(1/(2*sqrt(6)))..Pi/2),phi=0..Pi/6);

V := Int(Int(Int(r^2*sin(t),r = 3 .. 9),t = arccot(1/12*6^(1/2)) .. 1/2*Pi),phi = 0 .. 1/6*Pi)

>    V:=value(%);

V := 39/5*Pi